home *** CD-ROM | disk | FTP | other *** search
/ Language/OS - Multiplatform Resource Library / LANGUAGE OS.iso / prolog / modprolg / mod-prol.lha / Prolog / cmplib / src / $flatten1.P < prev    next >
Text File  |  1992-01-24  |  4KB  |  98 lines
  1. /************************************************************************
  2. *                                    *
  3. * The SB-Prolog System                            *
  4. * Copyright SUNY at Stony Brook, 1986; University of Arizona, 1987    *
  5. *                                    *
  6. ************************************************************************/
  7.  
  8. /*-----------------------------------------------------------------
  9. SB-Prolog is distributed in the hope that it will be useful,
  10. but WITHOUT ANY WARRANTY.  No author or distributor
  11. accepts responsibility to anyone for the consequences of using it
  12. or for whether it serves any particular purpose or works at all,
  13. unless he says so in writing.  Refer to the SB-Prolog General Public
  14. License for full details.
  15.  
  16. Everyone is granted permission to copy, modify and redistribute
  17. SB-Prolog, but only under the conditions described in the
  18. SB-Prolog General Public License.   A copy of this license is
  19. supposed to have been given to you along with SB-Prolog so you
  20. can know your rights and responsibilities.  It should be in a
  21. file named COPYING.  Among other things, the copyright notice
  22. and this notice must be preserved on all copies. 
  23. ------------------------------------------------------------------ */
  24. /* $flatten1.P */
  25.  
  26. /* **********************************************************************
  27. $flatten1_export([$add_uni_hdr/6,$flatten1/8]).
  28.  
  29. $flatten1_use : $blist, $listutil1, $glob, $meta
  30. ********************************************************************** */
  31.  
  32.  
  33. /* "$add_uni_hdr" adds the unifications resulting from the flattening of
  34.     nested structures in the head to the body of the clause.        */
  35.  
  36. $add_uni_hdr([],_,_,_,TGoal, TGoal).
  37. $add_uni_hdr([(V=S)|UniRest],A,NVars,Vlist,
  38.         TGoal, and('_call'(=,[V,S],NV), _, UGoal1)) :-
  39.     V = v(Vid,Prag), $member1(v(Vid,OccList),Vlist), Prag = vrec(_,_,_,_),
  40.     $gennum(Vno), $member1(o(Vno,1,1,A,t,Prag),OccList),
  41.     A1 is A+1, $member1(nv(NVars),NV),
  42.     $add_uni_hdr(UniRest,A1,NVars,Vlist,TGoal, UGoal1).
  43.  
  44. /*     "flatten" flattens each top-level argument, if necessary.    */
  45.  
  46. $flatten(Var, _, _, _, _, Var, _, _) :- Var = v(_, _).
  47. $flatten([Funcsym|ArgList],Vlist,Path,Lit,Arg,
  48.             [Funcsym|NArgList],UniList,BindList) :-
  49.     $flatten1(ArgList,Vlist,Path,Lit,Arg,NArgList,UniList,BindList).
  50.  
  51. /* "$flatten1" is given a list of the arguments of any structure at the top
  52.    level.  Any structure found in this list is nested and has to be flattened.
  53.    This flattening is done by flatten2, flatten1 just loops through calling
  54.    flatten2 with each of the arguments in the list given.        */
  55.  
  56. $flatten1([], _,_, _, _, [], _,_).
  57. $flatten1([H|T],Vlist,Path,Lit,Arg, [FH|FT], UniList,BindList) :-
  58.     $flatten2(H,Vlist,Path,Lit,Arg, FH, UniList,BindList),
  59.     $flatten1(T, Vlist,Path,Lit,Arg, FT, UniList,BindList).
  60. $flatten2(Var, _,_,_, _, Var, _,_) :- Var = v(_, _), !.
  61. $flatten2(Cons,_,_,_, _, Cons, _,_) :-
  62.     $length(Cons, L),
  63.     L < 2,
  64.     !.
  65. $flatten2(Str, Vlist, Path, Lit,Arg, v(Temp, Prag), UniList,BindList) :-
  66.     $flatten_make_var(Str,Vlist,UniList,
  67.                 BindList,Path,Lit,Arg,v(Temp,Prag),FStr),
  68.     $flatten(Str, Vlist, Path, Lit, Arg, FStr, UniList,BindList).
  69.  
  70. /* "$flatten_make_var" is called with a structure Str, and returns a variable
  71.     that replaces it in the process of flattening of nested structures. It
  72.     first searches BindList to see whether the structure has already been
  73.     flattened: if so, it returns the variable that had replaced it earlier,
  74.     and enters occurrence info for the variable, as well as other such
  75.     variables inside the flattened structure, into the symbol table: this may
  76.     result in some temporary variables becoming permanent. If no such variable
  77.     is found, a new one is generated.                    */
  78.  
  79. $flatten_make_var(Str,Vlist,UniList,BindList,Path,Lit,Arg,v(Vid,Prag),_) :-
  80.         $member2((v(Vid, _),Str1),BindList),
  81.         $flatten_same_str(Str, Str1), Prag = vrec(_,_,_,_),
  82.         $member1(v(Vid, OccList), Vlist), $gennum(N),
  83.         $member1(o(N,Path,Lit,Arg,s,Prag), OccList).
  84.  
  85. $flatten_make_var(Str,Vlist,UniList,BindList,Path,Lit,Arg,v(Vid,Prag),FStr) :-
  86.         $gensym('$',Vid), $gennum(N),
  87.         $member1(v(Vid, [o(N,Path,Lit,Arg,s,Prag)|_]), Vlist),
  88.         $member1((v(Vid,_),Str),BindList), Prag = vrec(_,_,_,_),
  89.         $member1((v(Vid,_) = FStr), UniList).
  90.  
  91. $flatten_same_str([], []).
  92. $flatten_same_str(v(Vid, X), v(Vid, Y)).
  93. $flatten_same_str([Func|Args1], [Func|Args2]) :-
  94.     $flatten_same_str(Args1, Args2).
  95.  
  96. /* ---------------------------- $flatten1.P ---------------------------- */
  97.  
  98.